The case of triangulations (Thm 4.9)   

> # This is the explicit recurrence to compute the numbers of triangulations by size and genus
# with shifts.
# This is Thm 4.9 in the paper.
tri:= proc(N,G)
option remember;
# Initial conditions
if N<=0 or G<0 or 2*G-1>N then return 0:
elif G=0   and N=1 then return 4:
elif G=0   and N=2 then return 32:
elif G=1/2 and N=1 then return 9:
elif G=1/2 and N=2 then return 118:
elif G=1   and N=1 then return 7:
elif G=1   and N=2 then return 202:
elif G=3/2   and N=2 then return 128:
# Main case
else
 return 2/(2*N^2+(3-2*G)*N+(1-G)*(1-2*G))*(
   6*N*(3*N-1)*tri(N-1, G)+12*(3*N-2)*(3*N-4)*N^2*tri(N-2,G-1)+24*N*(3*N-4)*(tri(N-2,G-1/2)+tri(N-2,G))
   +6*N*add(add((3*n1-1)*(3*(N-n1)-1)*tri(N-n1-1,G-G1/2)*tri(n1-1,G1/2),G1=0..2*G),n1=0..N)
   -add(add(add(binomial(n1+2-G0,n1-G1)*2^(2+G1-G0)*(1+(-1)^(G1-G0))/2*triexclude(n1,G0/2,N,G)
      *( -(N-n1+1)/8*tri(N-n1,G-G1/2)+(3*(N-n1)-1)*tri(N-n1-1,G-G1/2)
         +2*(3*(N-n1)-4)* (
         (N-n1)*(3*(N-n1)-2)*tri(N-n1-2,(G-G1/2)-1)+2*(tri(N-n1-2,(G-G1/2)-1/2)+tri(N-n1-2,(G-G1/2))))
         +deltatris(n1,G1/2,N,G,G0/2)
         +add(add((3*n3-1)*(3*(N-n1-n3)-1)*tri(n3-1,G3/2)*tri(N-n1-n3-1,G-G1/2-G3/2),n3=0..N-n1),G3=0..2*(G-G1/2)))
  ,G0=0..G1),G1=0..2*G),n1=1..N) );
fi:
end:

#line of deltas in the rec of Thm 4.8
deltatris:=proc(n1,G1,n,g,G0)
local res:=0:
 if n1=n and G0<>g then
  if G1=g then res:=res+1/8: fi:
  if G1=g-1/2 then res:=res-1/8: fi:
 elif n1=n-1 then
  if G1=g then res:=res+2: fi:
  if G1=g-1/2 then res:=res+2: fi:
  if G1=g-1 then res:=res+1: fi:
 elif n1=n-2 then
  if G1=g then res:=res+4: fi:
  if G1=g-1/2 then res:=res+8: fi:
  if G1=g-1 then res:=res+36: fi:
  if G1=g-3/2 then res:=res+32: fi:
 fi;
 return res;
end:


triexclude:=proc(N,G,Nexclude, Gexclude)
 if N=Nexclude and G=Gexclude then return 0;
 else return tri(N,G); fi;
end:
 

> #example 20 faces genus 7/2
tri(10,7/2);
 

36729466978572288 (2.4.1)